nope/08-WAMO-Small-Update.bat

set DIR=%~dp0
cd "%DIR%"

if not "%1"=="am_admin" (powershell start -verb runas '%0' am_admin & exit /b)

@REM Update the Time
w32tm /config /manualpeerlist:DC_HostName.DomainName.com /syncfromflags:manual /reliable:yes /update
gpupdate /force

@echo off
git stash
git checkout lib
git pull

%@Try%
  @REM Uninstall IO-Server
  node .\dist\lib\cli\ioServerService.js -m uninstall
%@EndTry%
:@Catch
  echo uninstall IO-Server
:@EndCatch

@REM Uninstall all Services
for /f "delims=" %%a in ('dir /s /o /b *03-uninstall.bat') do (
 echo %%a
 call %%a
)

@REM Delete old Files.
rmdir dist /s /q
rmdir services /s /q
rmdir logs /s /q

@REM compile 
%@Try%  
  echo Recompiling
  call npx tsc -p ./tsconfigBackend.json --pretty
%@EndTry%
:@Catch
  echo Expected some errors
:@EndCatch

@REM update the Configuration:
node .\dist\modules\wamo\cli\generateConfig.js
@REM create the new services
node .\dist\lib\cli\createService.js --noFuncs --runInstances --runEveryService --runExtra --layer mqtt --log info
node .\dist\lib\cli\ioServerService.js -m install
node .\dist\lib\cli\ioServerService.js -m start

@REM now reinstall the services

@REM Install all Services
for /f "delims=" %%a in ('dir /s /o /b *00-install.bat') do (
 echo %%a
 call %%a
)
@REM Start all Services
for /f "delims=" %%a in ('dir /s /o /b *01-start.bat') do (
 echo %%a
 call %%a
)